Magnum One/Magnum One (Mid-American Digital) (Disc Manufacturing).iso/d12/ccas01.arc/_XENIX.ASM

Assembly Source File | 1986-03-15 | 10.0 KB | 480 lines

title MSDOS 2.00 Function Library for Lattice C
TRUE    EQU    0
FALSE    EQU    -1
;
;........................................
;.                    .
;.    DOS 2.00 Functions for        .
;.           Lattice            .
;.                    .
;.    T. Jennings 23 June 83        .
;.      created 13 Sept 82        .
;.                    .
;........................................
;
;MSDOS 2.00 support for Lattice. These will NOT
;work for version 1.xx of DOS. All support full
;paths. The function names are the same as the
;standard library names with "_x" prepended, to
;accomodate my file system nameing heirarchy.
;
;NOTE: You cannot mix these calls with the
;Lattice library calls: i.e. open with _xopen()
;and write with open(). You must use ALL or
;NONE.
;
;These functions all use the DOS buffers.
;
;Detailed info is given in the title block for
;each function. A quick description follows.
;
;handle= _xopen(pathname,access);
;int handle,access;
;char *pathname;
;
;    Open a file. handle returns either
;the DOS handle, or -1 if error (file not
;found). Access is: 0 == read only, 1 == write
;only, 2 == read/write.
;
;handle= _xcreat(pathname,access);
;
;    Create a new file, delete any existing
;copy. Access is not used: use 0. Returns the
;handle or -1 if error.
;
;v= _xread(handle,buffer,count);
;v= _xwrite(handle,buffer,count);
;int v,handle,count;
;char *buffer;
;
;    File read or write to an opened or
;created file. reads or writes 'count' bytes
;to the file 'handle', to or from 'buffer'.
;Returns the number of bytes processed: equal
;to 'count' if sucessful.
;
;error= _xclose(handle)
;int error;
;
;    Close an open file. Returns -1 if
;error. Any buffers are flushed at this point.
;
;_xdelete(pathname);
;
;    Remove the file from the file
;system.
;
;fsize= _fsize(pathname);
;long fsize;
;
;    Returns the size of the file in bytes.
;Returns 0 if no file. Do NOT call inbetween
;calls to _xfind().
;
;found= _xfind(pathname,filename,&fsize,attrib,flag);
;int found,flag,attrib;
;char *pathname,filename[14];
;long fsize;
;
;Search for the specified pathname. flag should
;be 0 for the first call, non-zero for all
;subsequent calls. _xfind() returns true if a
;match was found, and the found file is
;returned in filename[], in ASCIZ format.
;Attrib is the DOS attributes to match; I
;will not describe that mess here. _xfind()
;returns the size of the file in fsize. (Don't
;forget to pass the address of fsize.)
; For example:
;
;int i;
;char filename[14];
;long fsize;
;
;    i= 0;
;    while (_xfind("\\bin\\*.*",filename,&fsize,0,i)) {
;        printf("File: %14s Size: %lu\n",filename,fsize);
;        ++i;
;    }
;    printf("%u matching files.\n",i);
;
;Prints the names of all matching disk files.
;Any other calls (except_fsize()) can be made
;in between calls to _xfind().
;
dgroup group data
pgroup group prog

prog segment byte public 'prog'

public    _xopen,_xcreat,_xclose
public    _xread,_xwrite
public    _xfind,_XLSEEK
public    _xfsize,_XCHMOD,_XEXIT
public     _xdelete,_XUNLINK,_XWAIT,_XGETDIR,_XCHDIR
assume cs:pgroup,ds:dgroup
;;
;;    _XLSEEK to a position within the file.
;;Reminder: The second argument is a long (32bit)
;;integer and this routine returns a 32bit integer
;;
;;    pos = _XLSEEK(handle,offset,mode);
;;
;;    long pos;        -1 if error, new file
;;                position if successful
;;    int handle;        file handle
;;    long offset;        desired position
;;    int mode;        offset mode:
;;                0 = relative to beginning of file
;;                1 = relative to current position
;;                2 = relative to end-of-file
;;
_XLSEEK    PROC    NEAR
    PUSH    BP
    MOV    BP,SP
    MOV    BX,[BP+4]
    MOV    DX,[BP+6]    ;LSW of offset
    MOV    CX,[BP+8]    ;MSW of offset
    MOV    AX,[BP+10]    ;mode (in AL only)
    MOV    AH,42H
    INT    21H
    JNC    LSKGR
    MOV    AX,FALSE
    MOV    BX,AX
    POP    BP
    RET
LSKGR:    MOV    BX,AX
    MOV    AX,DX
    POP    BP
    RET
_XLSEEK    ENDP
;;
;;    ret = _XCHMOD(path,attribute);
;;
;;    int ret;        error codes
;;    char *path;        null terminated drv:\path\filename.ext
;;    int attribute;        attribute to set file to
;;
_XCHMOD    PROC    NEAR
    PUSH    BP
    MOV    BP,SP
    MOV    AX,4301H    ;Function 43H, al=01H CX contains attribute
    MOV    DX,[BP+4]
    MOV    CX,[BP+6]
    INT    21H
    MOV    AX,TRUE
    JNC    CHMODGR
    DEC    AX
CHMODGR:POP    BP
    RET
_XCHMOD    ENDP
;;
;;    _XEXIT(exitcode);    THE RIGHT WAY TO DO IT.
;;                SETS ERRORLEVEL = EXITCODE
;;
;;    int exitcode;        0 normal exit; otherwise an error occurred
;;
_XEXIT    PROC    NEAR
    PUSH    BP
    MOV    BP,SP
    MOV    AX,[BP+4]
    MOV    AH,4CH
    INT    21H        ;DOESN'T RETURN...
_XEXIT    ENDP

;;    ret = _XWAIT()        Wait for a child process to terminate
;;
;;    int ret;        The return code given from _XEXIT(code)
;;
_XWAIT    PROC    NEAR
    PUSH    BP
    MOV    BP,SP
    MOV    AH,04DH
    INT    21H        ;Return code(s) in AH,AL
    POP    BP
    RET
_XWAIT    ENDP
;;
;;    ret = _XGETDIR(pathname,drive);
;;
;;    int ret;        ret = -1 if error
;;    char pathname;        The returned path name "path\filename.ext\0"
;;                null terminated and NO leading backslash and
;;                NO drive letter
;;    int drive;        The drive to get the current dir of.
;;                0 = default, 1 = A, etc.
;;
_XGETDIR PROC    NEAR
    PUSH    BP
    MOV    BP,SP
    MOV    AH,47H
    MOV    SI,[BP+4]
    MOV    DX,[BP+6]
    AND    DX,0FFH
    INT    21H
    JNC    GDRET
    MOV    AX,FALSE
GDRET:    POP    BP
    RET
_XGETDIR ENDP

;;    ret = _XCHDIR(path);
;;
;;    int ret;        ret = -1 if error (path not changed)
;;
;;    char path;        path to set.  Nul terminated WITH drive
;;
_XCHDIR    PROC    NEAR
    PUSH    BP
    MOV    BP,SP
    MOV    DX,[BP+4]
    MOV    AH,3BH
    INT    21H
    JNC    CDRET
    MOV    AX,FALSE
CDRET:    POP    BP
    RET
_XCHDIR    ENDP

;;
;;    handle= _xcreat(name,access)
;;    handle= _xopen(name,access)
;;
;;    int handle;        -1 if error,
;;    int access;        0=r, 1=w, 2=r/w
;;    char *name;        null terminated
;;
;;Open and create functions. The name is a null
;;terminated string. The access byte is passed
;;directly to DOS. All errors are translated to
;;a -1 return value.
;;
_xopen proc near
    mov    ah,61
    jmp    short opncrt
_xcreat    proc near
    mov    ah,60

opncrt:    push    bp
    mov    bp,sp
    mov    dx,[bp+4]    ;pathname,
    mov    al,[bp+6]    ;access,
    xor    bx,bx
    xor    cx,cx
    int    21h        ;do it,
    jnc    opncrt1
    mov    ax,-1        ;error!
opncrt1:pop    bp
    ret

_xcreat    endp
_xopen endp
;;
;;_xclose(handle)
;;int handle;
;;
;;Close a handle opened by _XOPEN or _XCREATE.
;;Returns -1 if close error.
;;
_xclose proc near
    mov    ah,62
    push    bp
    mov    bp,sp
    mov    bx,[bp+4]    ;handle,
    int    21h
    pop    bp
    ret

_xclose endp
page
;;
;;    count= _xread(handle,buffer,size)
;;    count= _xwrite(handle,buffer,size)
;;
;;    int count;    bytes actually r/w
;;    int handle;
;;    char *buffer;
;;    int size;    byte count,
;;
;;    Read or write (size) bytes from the
;;file (handle). The return value is the number
;;of bytes actually processed.
;;
;;    No text translation is done. All
;;bytes are processed as read or written. No
;;check is done (or is possible) on the buffer
;;size.
;;
;;    THE ERROR PART RETURNS -1 IF AN ERROR
;;HAS TAKEN PLACE DURING A _XREAD OR _XWRITE.
;;TAKEN FROM SIG/86 NEWSLETTER VOL 3 NUMBER 3
;;BY JOSEPH BOYKIN.
;;    PLACED HERE BY ALAN MINCHEW 8/24/84.
;;
_xread proc near
    mov    ah,63
    jmp    short rdwrt
_xwrite proc near
    mov    ah,64

rdwrt:    push    bp
    mov    bp,sp
    mov    bx,[bp+4]    ;handle,
    mov    cx,[bp+8]    ;count,
    mov    dx,[bp+6]    ;buffer,
    int    21h
    JNC    RWERR        ;ERROR CHECK PART TAKEN FROM
    MOV    AX,-1        ; XENIX CALLS BY Joe Boykin in SIG/86 V3.N3
RWERR:    pop    bp
    ret

_xwrite endp
_xread endp
page
;;
;;    ret= xfind(path,name,size,attrib,first)
;;    int ret;        0 if no match
;;    char *path;
;;    char *name;        dest name,
;;    long *size;        ptr to file siz
;;    int attrib;        attributes
;;    int first;        0 if 1st time,
;;
;;Find the Nth occurence of pathname. Returns
;;0 when no match. Only the filename portion
;;can contain wildcards. The returned filename
;;does not contain the path portion of the
;;input string.
;;    Not recursive. Do not call _FSIZE
;;inbetween _XFIND calls.
;;
xfpath    equ    4    ;path pointer,
xfname    equ    6    ;retnd name,
xfsize    equ    8    ;file size ptr,
xfaccess equ    10    ;access,
xfflag    equ    12    ;first time flag,

_xfind proc near
    push    bp
    mov    bp,sp
    mov    ah,26        ;set DMA addr
    mov    dx,offset dgroup:xfbuf
    int    21h        ;to buffer,
    test word ptr [bp+xfflag],-1
    mov    ah,78        ;do right call,
    jz    xf1
    mov    ah,79        ;0 == 1st time,
xf1:    mov    dx,[bp+xfpath]    ;path name,
    mov    cx,[bp+xfaccess];access,
    int    21h
    mov    ax,0        ;ret if no
    jc    xfr        ;match,
;
;Copy the file size in.
;
    mov    bx,[bp+xfsize]    ;size ptr,
    mov    ax,fsize
    mov    [bx],ax
    mov    ax,fsize+2
    mov    [bx+2],ax

    mov    di,[bp+xfname]    ;dest string,
    mov    si,offset dgroup:fname
    mov    cx,12
    cld
    mov    ax,ds        ;set ES == DS,
    mov    es,ax
;
;Fix a "slight" XENIX bug: Delete trailing
;spaces, else it fails OPENs.
;
xf2:    lodsb            ;get a byte,
    cmp    al,0        ;if null
    je    xf3
    cmp    al,' '        ;or space,
    je    xf3        ;stop,
    stosb
    loop    xf2        ;max 11 chars
xf3:    mov byte ptr [di],0    ;terminate,
    mov    ax,1        ;good return.
xfr:    pop    bp
    ret
_xfind endp
page
;;
;;    fsize= _xfsize(filename)
;;    long fsize;
;;    char *filename;
;;
;;Return the size of a file, in bytes. Returns
;;0 if file not found. Filename can contain
;;a path.
;;
;;Cannot be called in between any _XFIND calls.
;;
_xfsize proc near
    push    bp
    mov    bp,sp
    mov    ah,26        ;set DMA addr
    mov    dx,offset dgroup:xfbuf
    int    21h        ;to buffer,
    mov    ah,78        ;search 1st,
xs1:    mov    dx,[bp+4]    ;path name,
    mov    cx,0
    int    21h
    mov    ax,0        ;ret if no
    mov    bx,0        ;match,
    jc    xsr

    mov    bx,fsize
    mov    ax,fsize+2
xsr:    pop    bp
    ret
_xfsize endp
page
;
;error= _xdelete(path);        OR    ERROR = _XUNLINK(PATH);
;int error;        0 IF SUCCESSFUL; -1 IF ERROR
;char *path;
;
_XUNLINK PROC NEAR
_xdelete proc near
    push    bp
    mov    bp,sp
    mov    dx,[bp+4]
    mov    ah,41h
    int    21h
    mov    ax,0
    JNC    UNLKGR
    DEC    AX
UNLKGR:    pop    bp
    ret
_xdelete endp
_XUNLINK ENDP

prog ends
page
data segment word public 'data'
;
;Structure for the FindFirst and FindNext
;function XFIND. NOT REENTRANT.
;
xfbuf    db    (?)    ;search attrib
    db    (?)    ;drive,
    db 11 dup (?)    ;name,
    dw    (?)    ;last ent
    dd    (?)    ;DPB,
    dw    (?)    ;dir start

    db    (?)    ;attrib found,
    dw    (?)    ;time?
    dw    (?)    ;date?
fsize    dw    (?)    ;size low
    dw    (?)    ;size hi,
fname    db 13 dup (?)    ;packed name,

data ends

    end